Orange FTTH / SuperNova / Neostrada – Mikrotik + TV

Konfigurujemy Mikrotika 

Sposób konfiguracji urządzeń Mikrotika powinien pojawić się co najmniej rok wstecz na tym blogu, pozwólcie jednak że to w dniu dzisiejszym ten długi okres wyczekiwania wynagrodzę wam pełną konfiguracją umożliwiającą implementację światłowodu od Orange z działającą TV i komunikacją IPV4 i IPV6.

Jest to poprawnie działająca konfiguracja umożliwiająca całkowite schowanie FunBoxa 2.0 do pudełka, z pozostawieniem tylko ONT.
Niestety autoryzacje ONT uniemożliwiają nam włożenie wkładki SFP do naszego mikrotika.

Mój Mikrotik którego używam w ostatnim czasie to RB3011, sprzęt który wydaje się być jedynym rozsądnym z tej półki cenowej umożliwiającej pełne wysycenie pasma w najwyższej oferowanej opcji neostrady/supernovej czyli 600 Mbps.

Poniższa konfiguracja którą wam przedstawie umożliwia zaimplementowanie do 3 łączy.
Ether1 – to nasza wspomniana neostrada
Ether2 – to nasze dodatkowe łącze od innego operatora kablowego
Ether4 – ewentualny operator kablowy

/interface bridge
add name=LAN
add name=TV
add name=VOD
/interface ethernet
set [ find default-name=ether1 ] comment="Internet ETH1 - Orange" name=ORANGE
set [ find default-name=ether2 ] comment="Internet ETH2 - UPC" name=UPC
set [ find default-name=ether3 ] comment="Interface TV Orange" name=ether3-tv
set [ find default-name=ether4 ] comment="Interface WAN#3"
set [ find default-name=ether5 ] comment="Interface LAN"
set [ find default-name=sfp1 ] comment=Unused
/interface vlan
add interface=ORANGE mtu=1492 name=vlan-orange vlan-id=35
add interface=ORANGE name=vlan-tv vlan-id=839
add interface=ORANGE name=vlan-vod vlan-id=838
/interface pppoe-client
add add-default-route=yes comment="Interface Diall Out PPPOE" \
    default-route-distance=1 disabled=no interface=vlan-orange \
    keepalive-timeout=disabled name=pppoe-orange password=passwd \
    use-peer-dns=yes user=użyszkodnik@neostrada.pl
/interface list
add name=iptv
add name=internet
/ip dhcp-client option
add code=60 name=vendor-class-identifier value="'sagemcom'"
add code=61 name=dhcp-client-identifier value=0x01aabbccddeeff <- zamień aabbccddeeff na właściwy mac address FunBoxa
add code=77 name=user-class value="0x2646535644534c5f66756e626f78322e4d4c54562e736f66746174686f6d652e46756e626f7832"
/ip pool
add name=pool-net ranges=192.168.1.10-192.168.1.199
add name=pool-iptv ranges=192.168.2.10-192.168.2.20
/ip dhcp-server
add address-pool=pool-net disabled=no interface=LAN lease-time=3d name=\
    dhcp-net
add address-pool=pool-iptv disabled=no interface=ether3-tv lease-time=3d \
    name=dhcp-iptv
/port
set 1 name=usb2
/interface ppp-client
add apn=internet info-channel=1 name=ppp-out1 port=usb2
/queue tree
add name=out-queue parent=ORANGE queue=default
add name=in-queue parent=ether3-tv queue=default
add name=in-queue-iptv packet-mark=iptv parent=in-queue queue=default
add name=out-queue-iptv packet-mark=iptv parent=out-queue queue=default
/interface bridge filter
add action=mark-packet chain=input comment="Mark packets IPTV" in-interface=\
    vlan-vod new-packet-mark=iptv
add action=mark-packet chain=input in-interface=vlan-tv new-packet-mark=iptv
add action=set-priority chain=output comment=\
    "Set 802.1p for IPTV out packets" new-priority=4 out-interface=vlan-vod \
    passthrough=yes
add action=set-priority chain=output new-priority=5 out-interface=vlan-tv \
    passthrough=yes
/interface bridge port
add bridge=TV interface=vlan-tv
add bridge=VOD interface=vlan-vod
add bridge=LAN interface=ether10
add bridge=LAN interface=ether9
add bridge=LAN interface=ether8
add bridge=LAN interface=ether7
add bridge=LAN interface=ether6
add bridge=LAN interface=ether5
add bridge=LAN interface=ether4
/interface bridge settings
set use-ip-firewall=yes use-ip-firewall-for-vlan=yes
/interface list member
add interface=VOD list=iptv
add interface=TV list=iptv
add interface=ether3-tv list=iptv
add interface=UPC list=internet
add interface=pppoe-orange list=internet
/ip address
add address=192.168.1.1/24 comment=LAN interface=LAN network=192.168.1.0
add address=192.168.2.1/24 interface=ether3-tv network=192.168.2.0
add address=192.168.3.1/24 interface=TV network=192.168.3.0
/ip dhcp-client
add default-route-distance=210 dhcp-options=\
    vendor-class-identifier,dhcp-client-identifier,user-class,hostname \
    disabled=no interface=VOD
add default-route-distance=0 dhcp-options=hostname,clientid disabled=no \
    interface=UPC
/ip dhcp-server lease
add address=192.168.1.100 comment=Serwer mac-address=aa:bb:cc:dd:ee:ff \
    server=dhcp-net
/ip dhcp-server network
add address=192.168.1.0/24 dns-server=194.204.159.1,194.204.152.34 gateway=\
    192.168.1.1 netmask=24
add address=192.168.2.0/24 gateway=192.168.2.1 netmask=24
/ip firewall filter
add action=drop chain=input comment="Drop Invalid Connections" \
    connection-state=invalid
add action=drop chain=forward comment="Drop Invalid Connections" \
    connection-state=invalid
add action=fasttrack-connection chain=forward comment="defconf: fasttrack" \
    connection-state=established,related
add action=accept chain=input comment="Accept IPTV packets" \
    in-interface-list=iptv
add action=accept chain=forward in-interface=ether3-tv out-interface=\
    pppoe-orange
add action=accept chain=forward in-interface=ether3-tv out-interface=VOD
add action=accept chain=forward in-interface=TV out-interface=ether3-tv
add action=accept chain=forward connection-state=established,related \
    in-interface=VOD
add action=drop chain=forward comment="Drop all other IPTV packets" \
    in-interface-list=iptv
add action=accept chain=input comment=\
    "Accept Related or Established Connections" connection-state=\
    established,related
add action=accept chain=forward comment="Accept New Connections" \
    connection-state=new
add action=accept chain=forward comment=\
    "Accept Related or Established Connections" connection-state=\
    established,related
add action=accept chain=input comment="Forwarded Ports TCP/UDP" dst-port=\
    80 protocol=tcp
add action=accept chain=input dst-port=1194 protocol=udp
add action=drop chain=forward comment=\
    "defconf:  drop all from WAN not DSTNATed" connection-nat-state=!dstnat \
    connection-state=new in-interface-list=internet
/ip firewall nat
add action=masquerade chain=srcnat
add action=masquerade chain=srcnat out-interface=VOD
add action=dst-nat chain=dstnat comment="Port forwarding to serwer host" \
    dst-port=80 in-interface-list=internet protocol=tcp to-addresses=\
    192.168.1.100 to-ports=80
add action=dst-nat chain=dstnat dst-port=1194 in-interface-list=internet \
    protocol=udp to-addresses=192.168.1.100 to-ports=1194
/ip service
set telnet disabled=yes
set ssh disabled=yes
set www-ssl disabled=no
set api disabled=yes
set api-ssl disabled=yes
/lcd
set backlight-timeout=never default-screen=informative-slideshow \
    read-only-mode=yes
/lcd interface
add interface=pppoe-orange max-speed=1000Mbps
/routing igmp-proxy
set quick-leave=yes
/routing igmp-proxy interface
add alternative-subnets=0.0.0.0/0 interface=TV upstream=yes
add alternative-subnets=0.0.0.0/0 interface=ether3-tv
/system clock
set time-zone-name=Europe/Warsaw
/system ntp client
set enabled=yes primary-ntp=80.50.231.226 secondary-ntp=194.146.251.100
/system routerboard settings
set silent-boot=yes
/tool graphing interface
add interface=LAN
add interface=ORANGE
add interface=VOD
add interface=TV
add interface=UPC

Config należy poprawić w liniach 17,26
Aby uruchomić IPV6 wystarczy dodać dodatkowe linijki do konfiguracji

add add-default-route=yes allow=chap disabled=no interface=vlan-orange \
    keepalive-timeout=disabled max-mru=1492 max-mtu=1492 name=\
    pppoe-neostrada6 password=xxxxxx user=\ 
    bez_ochrony-użyszkodnik@neostrada.pl/ipv6 
/ipv6 address
add address=2a01:11XX:XXXX:XX00::1 eui-64=yes interface=LAN
/ipv6 dhcp-client
add add-default-route=yes interface=pppoe-neostrada6 pool-name=neostrada \
    pool-prefix-length=56 request=prefix

W przypadku IPV6 do zmiany są linie 1 i 6

Sytuacja możliwa do osiągnięcia tylko i wyłącznie w przypadku otrzymania od operatora FunBox 2.0 i ONT.
Nie jest możliwe skonfigurowanie takiego połączenia przy użyciu FunBox 3.0 ze względu na wbudowany ONT.
Na szczęście jest możliwość poproszenia o FunBoxy 2.0 nawet z dekoderem Samsung.

Opis został stworzony na podstawie moich i doświadczeń innych użytkowników urządzeń Mikrotik z forum Trzepak.pl